Live training: next batches coming soon. Join the waitlist:Waitlists open:Developer Training →Developer →Copilot Studio Training →Copilot Studio →

Power Apps Text Function (7 Practical Examples)

Dates in a Power Apps label rarely look the way your users expect. A due date shows up with a time of 12:00 AM, a price reads 1249 instead of $1,249.00, and ticket number 1 should really be SR-00001.

All three fixes come from one function. The Power Apps Text function takes a number, a date, or almost any other value and hands it back as a string in exactly the shape you describe.

In this tutorial, I’ll show you how to use the power apps text function with seven tested examples: predefined date formats, custom dates and times, currency, leading zeros, plain conversions, and a Filter where Text quietly breaks delegation.

Power Apps Text Function Syntax

The Text function in Power Apps comes in four forms:

Text( NumberOrDateTime, DateTimeFormatEnum [, ResultLanguageTag ] )
Text( NumberOrDateTime, CustomFormat [, ResultLanguageTag ] )
Text( AnyValue )
Text( Dynamic )
ParameterRequiredTypeDescription
NumberOrDateTimeYesNumber or date/timeThe value to format.
DateTimeFormatEnumThis or CustomFormatDateTimeFormat enumA predefined format, such as DateTimeFormat.LongDate.
CustomFormatThis or the enumTextPlaceholders in quotes, such as "mm/dd/yyyy".
ResultLanguageTagNoTextLanguage of the result, such as "es-ES". Default: the user’s language.
AnyValueYes (one-argument form)AnyConverted with a default format.

Return value: always a text string. You can’t do date math on the result, so format at the very end, in the label, not in the middle of a calculation.

The placeholders you’ll use most, with results from my test date (January 5, 2026, 6:30 PM):

PlaceholderShowsResult
0 / #Digit, padded / not padded"#.00" on 8.9 = 8.90
, and .Thousands separator, decimal point$1,249.00
mm / mmm / mmmmMonth: two digits, short, full01 / Jan / January
dd / ddd / ddddDay: two digits, short, full05 / Mon / Monday
yyyyFour-digit year2026
hh:mm + AM/PMTime, 12-hour with AM/PM06:30 PM

Delegation: Text is a column casting operation, so Power Apps can’t delegate it inside Filter or LookUp (my Power Apps delegation tutorial explains the 500-row limit). Example 7 shows what that costs. Text isn’t a behavior function, so it works in any property of a canvas app.

When to Use the Text Function in Power Apps

  • Show a SharePoint date as 01/05/2026 or Monday, January 5, 2026 in a gallery or form.
  • Show money with a dollar sign and commas, like in my Power Apps currency format tutorial.
  • Build fixed-width IDs such as SR-00001 from a number column.
  • Change the date format of a column in a Power Apps data table.
  • Turn a number or Boolean into text for a Notify message or a text column.
  • Build a readable date or amount before you send it to a Power Automate flow or post it in a Microsoft Teams message.

Example 1: Format a Date in Power Apps With DateTimeFormat

Let’s start simple: one fixed date, Friday, November 20, 2026, shown four ways. Each formula sits in its own modern Text label on a screen called scrFnText in my Power Apps demo app.

New to formulas? Select the label, pick Text in the property dropdown left of fx, and type in the formula bar. To test, click Play at the top right, or hold Alt and click.

Text label selected with the Text property chosen and a Text formula typed in the Power Apps formula bar
Text(Date(2026, 11, 20), DateTimeFormat.LongDate)
Text(DateTime(2026, 11, 20, 14, 30, 0), DateTimeFormat.ShortDateTime)
Text(DateTime(2026, 11, 20, 14, 30, 0), DateTimeFormat.LongTime24)
Text(Date(2026, 11, 20), DateTimeFormat.LongDate, "es-ES")
Preview showing LongDate, ShortDateTime, LongTime24 and Spanish LongDate results of the Text function

How does this work?

LongDate returns “Friday, November 20, 2026”. ShortDateTime gives “11/20/2026 2:30 PM”, and LongTime24 switches to the 24-hour clock: “14:30:00”. The language tag "es-ES" returns “viernes, 20 de noviembre de 2026”.

Pro Tip: Use the DateTimeFormat members for dates whenever you can. They adapt to each user’s language and region, which matters once your Power Apps app is shared with people in other countries.

Example 2: Format a SharePoint Date Column With a Custom Format

Sometimes you need an exact pattern, like a sortable yyyy-mm-dd. Here I read the DueDate of the first item in my Service Requests list, “Laptop replacement #1000”, due January 5, 2026.

Text(First('Service Requests').DueDate, "mm/dd/yyyy")
Text(First('Service Requests').DueDate, "dddd, mmmm d, yyyy")
Text(First('Service Requests').DueDate, "yyyy-mm-dd")
Custom date format dddd, mmmm d, yyyy typed in the formula bar for a SharePoint DueDate label

A gallery under the labels lists the first four requests, with this subtitle:

"Due " & Text(ThisItem.DueDate, "ddd, mmm d")
Preview of custom date formats and a gallery showing short due dates from SharePoint

How does this work?

mm/dd/yyyy returns “01/05/2026”, dddd, mmmm d, yyyy spells it out as “Monday, January 5, 2026”, and yyyy-mm-dd gives “2026-01-05”. Slashes, commas and spaces are copied as they are. The gallery shows “Due Mon, Jan 5” and “Due Sat, Jan 10”. For today’s date, use Today(), as in my Now, Today and IsToday tutorial.

Example 3: Show Date and Time (Hours, Minutes, AM/PM)

MeetingStart stores a date and time. SharePoint saves it in UTC, and Text shows it in the user’s time zone.

Text(First('Service Requests').MeetingStart, "mm/dd/yyyy hh:mm AM/PM")
Text(First('Service Requests').MeetingStart, "h:mm a/p")
Text(First('Service Requests').MeetingStart, "hh:mm")

Now the traps. Watch mm on its own, and uppercase letters:

Text(First('Service Requests').MeetingStart, "mm")
Text(First('Service Requests').MeetingStart, "hh") & ":" & Text(First('Service Requests').MeetingStart, "mm")
Text(First('Service Requests').MeetingStart, "MM/DD/YYYY")
Text formula with the mm placeholder alone returning 01, the month, in Power Apps Studio

Here are all six results in Preview:

Preview showing date and time results, mm returning the month and uppercase MM/DD/YYYY failing

How does this work?

The first formula returns “01/05/2026 06:30 PM”, h:mm a/p gives “6:30 p”, and hh:mm without AM/PM uses the 24-hour clock: “18:30”.

"mm" alone returns “01”, the month, because Power Apps reads mm as minutes only right after h/hh or before ss. Splitting hours and minutes repeats it: “18:01”. Uppercase "MM/DD/YYYY" isn’t a placeholder at all; it returned “MM/DD/YYYY1767618000000”.

Coming from Power Automate? Its formatDateTime() uses uppercase MM for the month and mm for minutes, so a format string copied from a flow won’t give you the month in Power Apps. Use lowercase here.

Pro Tip: Need one fixed zone, like Pacific, for everyone? See my Power Apps time zone tutorial.

Example 4: Format Numbers as Currency With Thousands Separators

I tested rounding, zero and negative values in single labels:

Text(1249, "$#,##0.00")
Text(2398.996, "#,##0.00")
Text(8.9, "#.00")
Text(0, "#,###")
Text(0, "#,##0")
Text(-1250, "$#,##0.00")
Preview of currency, rounding, zero and negative numbers formatted by the Text function

Then a gallery on a small inline table of order lines, with a total from the Sum function:

Table(
    {Item: "Laptop stand", Amount: 49.5},
    {Item: "Docking station", Amount: 1249},
    {Item: "Two 27-inch monitors", Amount: 2398.996},
    {Item: "Returned mouse", Amount: 0}
)
ThisItem.Item & ": " & Text(ThisItem.Amount, "$#,##0.00")

"Order total: " & Text(Sum(galTxOrders.AllItems, Amount), "$#,##0.00")
Gallery label formula formatting Amount as currency with the $#,##0.00 placeholder

How does this work?

$ is a literal, #,##0 adds a comma every three digits, and .00 forces two decimals. So 1249 becomes “$1,249.00”, 2398.996 rounds to “2,399.00”, and -1250 shows “-$1,250.00”. The total is “$3,697.50”.

Zero is the gotcha: "#,###" returned an empty label, while "#,##0" returned “0”.

Example 5: Add Leading Zeros to Build Ticket Numbers

The SharePoint ID column is a plain number, so I pad it in a gallery on the first four Service Requests:

"SR-" & Text(ThisItem.ID, "00000") & " | " & ThisItem.Title

Two single-value checks sit above the gallery:

Text(7, "00")
Text(0.875, "0.0%")
Gallery formula building SR- ticket numbers with Text and the 00000 placeholder

How does this work?

Each 0 in "00000" is a required digit, so the label reads “SR-00001 | Laptop replacement #1000”. Text(7, "00") returns “07”. The & joins the parts, the same way you concatenate text strings in Power Apps.

Careful with percentages: % isn’t a Power Apps placeholder. Text(0.875, "0.0%") returned “0.9%”, not 87.5%. Multiply by 100 first.

Example 6: Convert Numbers, Booleans and Dates to Plain Text

With one argument, Text converts a value with a default format, handy for text-only functions like the Len function.

Text(true)
Text(1234567.89)
Text(DateTime(2026, 11, 20, 14, 30, 0))
Len(Text(1234567.89))
Text(Now(), DateTimeFormat.UTC)
"[" & Text(Blank(), "mm/dd/yyyy") & "]"
Text(1249, "$#,##0.00") + 1
Preview of one-argument Text results for a Boolean, a number, a date, Len, UTC and Blank

How does this work?

Text(true) returns “true”, Text(1234567.89) returns “1234567.89” (no commas), and the DateTime comes back as “11/20/2026 2:30 PM”. Len counts 10 characters. DateTimeFormat.UTC gives ISO 8601, like “2026-11-17T00:51:11.340Z”.

A blank date returns empty text, no error. And Text(1249, "$#,##0.00") + 1 returned 1250, because Power Apps converted the text back to a number.

Example 7: Filter a SharePoint List by Month in Power Apps (Delegation Warning)

Here’s the mistake I see most: formatting the column to find every request due in September 2026. Service Requests has 623 rows, more than the 500-row default limit:

"Text filter: " & CountRows(
    Filter('Service Requests', Text(DueDate, "yyyy-mm") = "2026-09")
)
Delegation warning on a Filter formula that wraps the DueDate column in the Text function

The fix compares real dates, so SharePoint does the filtering:

"Date range: " & CountRows(
    Filter(
        'Service Requests',
        DueDate >= Date(2026, 9, 1),
        DueDate < Date(2026, 10, 1)
    )
)
Preview comparing the Text filter count of 30 with the delegable date range count of 60

How does this work?

Power Apps can’t send Text(DueDate, ...) to SharePoint, so it checks only the first 500 rows: “Text filter: 30”. The date range returns 60, the true count. Hover the underline and Studio warns that the “Text” part of the formula “might not work correctly on large data sets.”

The second label also shows a triangle, but its message is about CountRows, and the count is right.

Common Mistakes with the Power Apps Text Function

  • Minutes show the month. Keep mm right after hh in one string: "hh:mm".
  • Uppercase placeholders. Use lowercase; "MM/DD/YYYY" doesn’t format.
  • Zero disappears. End the number part with 0: "#,##0".
  • Text inside Filter. Not delegable; compare dates instead. Raising the Data row limit in the Power Apps settings (max 10,000) only hides it.
  • Wrong direction. Text turns values into text. For text to a number use the Value function; for text to a date use the DateValue function.

Wrapping Up

The Power Apps Text function turns numbers and dates into exactly the string you want: DateTimeFormat for dates that adapt to each user’s language, placeholders for currency, leading zeros and time, and one-argument Text for quick conversions in any canvas app. Just keep it out of Filter on a large SharePoint list.

Browse all Power Apps functions, or see the Text function on Microsoft Learn for the full placeholder list.

Other Power Apps functions you may find useful: